[OE-core] [PATCH 4/6] initial add fontforge(-native) 20141126

[Andreas Müller]

had this in my private layer but think it could be useful here.

Native tests: liberation-fonts (follow-up patch) / oxygen-fonts
Target test: gumstix overo / xfce image

Signed-off-by: Andreas Müller <schnitzeltony at googlemail.com>
---
 .../fontforge/fontforge_20141126.bb                | 43 ++++++++++++++++++++++
 1 file changed, 43 insertions(+)
 create mode 100644 meta/recipes-graphics/fontforge/fontforge_20141126.bb

diff --git a/meta/recipes-graphics/fontforge/fontforge_20141126.bb b/meta/recipes-graphics/fontforge/fontforge_20141126.bb
new file mode 100644
index 0000000..835aa9b
--- /dev/null
+++ b/meta/recipes-graphics/fontforge/fontforge_20141126.bb
@@ -0,0 +1,43 @@
+SUMMARY = "A font editor"
+HOMEPAGE = "http://fontforge.github.io/en-US/"
+LICENSE = "GPLv3"
+LIC_FILES_CHKSUM = " \
+    file://COPYING.gplv3;md5=d32239bcb673463ab874e80d47fae504 \
+    file://LICENSE;md5=71d636ba7678baa1573e1b531041386e \
+"
+
+inherit autotools pkgconfig pythonnative mime
+
+DEPENDS = "glib-2.0 pango giflib tiff libxml2 jpeg python libtool"
+DEPENDS_append_class-target = " libxi"
+
+SRC_URI = "https://github.com/${BPN}/${BPN}/archive/${PV}.tar.gz"
+SRC_URI[md5sum] = "0d6f5112c4e5689087339a94aceadf77"
+SRC_URI[sha256sum] = "9c90c640023463c0b2b97b87575a014fcf44f688c3763f4cd136d3c267092106"
+
+EXTRA_OECONF_append_class-native = " with_x=no --disable-python-extension --disable-python-scripting"
+
+do_configure_prepend() {
+    currdir=`pwd`
+    cd ${S}
+
+    ./bootstrap
+
+    cd $currdir
+}
+
+EXTRA_OEMAKE = "CFLAGS='${CFLAGS} -I${B}/uthash/src'"
+
+PACKAGES =+ "${PN}-python-dbg ${PN}-python"
+
+FILES_${PN} += " \
+    ${datadir}/mime \
+    ${datadir}/icons \
+"
+
+FILES_${PN}-python = "${PYTHON_SITEPACKAGES_DIR} ${datadir}/${PN}/python"
+FILES_${PN}-python-dbg = "${PYTHON_SITEPACKAGES_DIR}/.debug"
+RDEPENDS_${PN}-python = "python"
+
+# for kde's oxygen-fonts or liberation-fonts (> 1.04)
+BBCLASSEXTEND = "native"
-- 
1.9.3